# ex-4-NLP.mod
# 
# NLP formulation of Multi-Leader-Follower Game 
# 
# Example 4 from Fukushima and Pang, "Quasi-Variational Inequalities,
# Generalized Nash Equlibria, and Multi-Leader-Follower Games", to
# appear in Computational Management Science.
#
#######################################################################

# ... sets
set I := 1..2;

# ... primal variables
var x{I} >= 0, <= 1;         # ... leader 1 & 2
var y  >= 0;                 # ... follower
var s  >= 0;

# ... multipliers
var chiU{I}  >= 0;
var chiL{I}  >= 0;
var psi{I}   >= 0;
var sigma{I} >= 0;
var xi{I}    >= 0;
var mu{I};

minimize l1compl: sum{i in I}(   x[i]*chiL[i] + (1-x[i])*chiU[i]
                               + y*psi[i] + s*sigma[i] ) + y*s;

subject to
	# ... first order conditions; player 1
	KKT1x:   0.5 - mu[1] = chiL[1] - chiU[1];
	KKT1y:   1.0 - mu[1] = psi[1] - xi[1]*s;

	# ... first order conditions; player 2
	KKT2x: - 0.5 - mu[2] = chiL[2] - chiU[2];
	KKT2y: - 1.0 - mu[2] = psi[2] - xi[2]*s;

	# ... FO conditions wrt slacks s
	KKTs{i in I}: mu[i] - sigma[i] + xi[i]*y = 0;

	# ... definition of slacks
	DefS{i in I}: s = -1 + x[1] + x[2] + y;